2013 Macbook Air Pro 装不了Windows7 ，键鼠失效卡死 ...（测试可用）

admin 管理员组

文章数量: 887021

只要下载一个小小的工具～
这是一个bat批处理文件，通过向boot.wim和install.wim中添加驱动程序的方法来完美解决安装Windows7时键盘鼠标动不了的问题。
请另外寻找一台安装 Windows 7 系统的电脑运行，Windows xp 不支持。Mac暂时不支持。
先在OS X系统里用BootCamp走第一、二步骤，然后启动我的工具，顺序执行1～5步骤。工具里有放QQ的！
1～5全部执行完之后，请先在OS X系统里用BootCamp走第三步，再U盘插入MacBook Air，开机按住，选择U盘启动即可！接下来按照正常方式安装即可。选择分区的时候记得选择BOOTCAMP分区。

Pro还没有正式试过，可能存在皆容性问题。MacBook Air 是没问题的。请Pro用户单独和我联系。工具里有放QQ。

http://pan.baidu/s/1nt4UVMT

install.bat

@echo off
title Windows 7 驱动加载程序 v1.3
ver | find "4.0." > NUL && set WOS=Windows 95
ver | find "4.1." > NUL && set WOS=Windows 98
ver | find "4.9." > NUL && set WOS=Windows ME
ver | find "5.0." > NUL && set WOS=Windows 2000
ver | find "5.1." > NUL && set WOS=Windows xp
ver | find "5.2." > NUL && set WOS=Windows 2003
ver | find "6.0." > NUL && set WOS=Windows vista
ver | find "6.1." > NUL && set WOS=Windows 7
ver | find "6.2." > NUL && set WOS=Windows 8
ver | find "6.3." > NUL && set WOS=Windows 8.1
echo ----------------------------------------------------------------
echo                 欢迎使用Windows 7 USB3.0 驱动加载程序
echo 本程序可以有效的解决在Macbook Air 2013年中期版本中用BootCamp安装
echo Windows 7时出现的键盘鼠标失灵的问题。
echo 正在自我检查...
@echo users test>%windir%\tester.tmp||set users=0
if "%users%"=="0" (
echo 请以管理员身份运行该程序！&echo 方法：右键点击我，选择“以管理员权限运行”
) else (
del %windir%\tester.tmp&echo 用户权限检查正常。)
set osok=0
if "%WOS%"=="Windows 7" set osok=1
if "%WOS%"=="Windows 8" set osok=1
if "%WOS%"=="Windows 8.1" set osok=1
if "%osok%"=="1" (
echo 系统版本检查正常：%WOS%
) else (
echo 系统版本不合要求，本程序要求在Windows 7或Windows 8中运行，而你的
echo 系统版本是 %WOS%。
set users=0
)
echo 千万注意，本程序不可以在可移动磁盘中运行，只能在本地磁盘中运行。
set voice=欢迎进入 Windows 7 驱动加载程序
echo ----------------------------------------------------------------
cd /d %~dp0
pause
if "%users%"=="0" exit
if "%osok%"=="0" exit
cls
echo ----------------------------------------------------------------
:inputc
set /p desk=请输入U盘启动盘盘符[示例：e(小写，不带":"和"\")]  
echo 正在自我检查...
set desktf=0
for %%i in (%desk%) do if exist %%i:\sources\boot.wim (
set desktf=1
) else (
set desktf=0
)
for %%i in (%desk%) do if exist %%i:\sources\install.wim (
set desktf=1
) else (
set desktf=0
)
if "%desktf%"=="1" for %%i in (%desk%) do if exist %%i:\$WinPEDriver$ (
set desktf=1
) else (
set desktf=2
)
if "%desktf%"=="2" echo 该盘中无BootCamp支持文件，请检查是否用BootCamp加载了支持文件。&pause&goto inputc
if "%desktf%"=="1" echo 自我检查正常！
if "%desktf%"=="0" echo 不存在此盘符或此盘符不是标准的Windows 7安装磁盘。
if "%desktf%"=="0" goto inputc
echo ----------------------------------------------------------------
pause
cls
:sc
:input
cls
echo ----------------------------------------------------------------
echo 请选择你要进行的任务：
echo 1、复制U盘中的驱动到工作目录
echo 2、复制U盘中要加载驱动的镜像到工作目录
echo 3、给boot.wim加载驱动
echo 4、给install.wim加载驱动
echo 5、复制工作目录中的已经加载好驱动的镜像到U盘
echo 6、退出程序
echo ----------------------------------------------------------------
set /p task=任务编号(1~6):
cls
if "%task%"=="1" goto copy3
if "%task%"=="2" goto copy1
if "%task%"=="3" goto boot
if "%task%"=="4" goto install
if "%task%"=="5" goto copy2
if "%task%"==“6” exit


:copy1
echo ----------------------------------------------------------------
echo 正在拷贝Windows安装镜像到工作目录...
for %%i in (%desk%) do copy %%i:\sources\boot.wim %~dp0
for %%i in (%desk%) do copy %%i:\sources\install.wim %~dp0
echo 拷贝成功！
echo ----------------------------------------------------------------
pause
set sendcode=拷贝Windows安装镜像到工作目录，2
set voice=拷贝Windows安装镜像到工作目录已完成
goto sc


:copy2
echo ----------------------------------------------------------------
echo 正在进行自我检查..
if not exist boot.wim goto exit1
if not exist install.wim goto exit1
echo 存在Windows安装文件。
echo 自我检查完毕！不存在任何问题！
echo 正在拷贝Windows安装镜像到U盘启动盘...
for %%i in (%desk%) do copy /y %~dp0install.wim %%i:\sources
for %%i in (%desk%) do copy /y %~dp0boot.wim %%i:\sources
del /q install.wim
del /q boot.wim
rd /q/s Drivers
echo 正在删除限制文件...
for %%i in (%desk%) do del %%i:\sources\ei.cfg
echo 删除完成，已经可以自由选择系统版本。
echo 拷贝成功！
echo ----------------------------------------------------------------
set sendcode=拷贝Windows安装镜像到U盘启动盘，5
set voice=拷贝Windows安装镜像到优盘启动盘已完成
pause
goto sc


:copy3
echo ----------------------------------------------------------------
echo 正在复制U盘中的BootCamp支持文件到工作目录...
md Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\HCSwitch\Win7\x64\iusb3hcs.cat %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\HCSwitch\Win7\x64\iusb3hcs.inf %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\HCSwitch\Win7\x64\iusb3hcs.sys %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\HCSwitch\Win7\x64\WdfCoInstaller01009.dll %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\iusb3hub.cat %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\iusb3hub.inf %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\IUsb3Hub.man %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\iusb3hub.sys %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\iusb3xhc.cat %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\iusb3xhc.inf %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\iusb3xhc.man %~dp0Drivers
for %%i in (%desk%) do copy %%i:\$WinPEDriver$\IntelxHCISetup\Drivers\xHCI\Win7\x64\iusb3xhc.sys %~dp0Drivers
echo 成功复制所有BootCamp支持文件。
echo -----------------------------------------------------------------
set sendcode=拷贝驱动到工作目录，1
set voice=拷贝驱动到工作目录已完成
pause
goto sc


:boot
echo ----------------------------------------------------------------
echo 正在进行自我检查..
if not exist boot.wim goto exit1
echo 存在Windows安装文件。
if exist Drivers\iusb3hcs.inf echo 存在BootCamp支持文件
if not exist Drivers\iusb3hcs.inf echo 不存在BootCamp支持文件&echo 即将开始执行BootCamp支持文件复制程序&pause&goto copy3
echo 自我检查完毕！不存在任何问题！即将开始加载驱动程序。
echo ----------------------------------------------------------------
echo 开始加载boot.wim的驱动程序...
md mount
dism /mount-wim /wimfile:boot.wim /index:2 /mountdir:mount
dism /image:mount /add-driver /driver:Drivers\iusb3hub.inf
dism /image:mount /add-driver /driver:Drivers\iusb3xhc.inf
dism /image:mount /add-driver /driver:Drivers\iusb3hcs.inf
dism /unmount-wim /mountdir:mount /commit
echo boot.wim的驱动程序已经加载完毕。
del /q mount
set sendcode=加载boot.wim的驱动，3
set voice=已成功加载boot.wim的驱动
rd /q/s mount
pause
goto sc


:install
md mount
echo ----------------------------------------------------------------
echo 正在进行自我检查..
if not exist install.wim goto exit1
echo 存在Windows安装文件。
if exist Drivers\iusb3hcs.inf echo 存在BootCamp支持文件
if not exist Drivers\iusb3hcs.inf goto exit2
echo 自我检查完毕！不存在任何问题！即将开始加载驱动程序。
echo ----------------------------------------------------------------
echo 开始加载install.wim的驱动程序...
dism /mount-wim /wimfile:install.wim /index:4 /mountdir:mount
dism /image:mount /add-driver /driver:Drivers\iusb3hub.inf
dism /image:mount /add-driver /driver:Drivers\iusb3xhc.inf
dism /image:mount /add-driver /driver:Drivers\iusb3hcs.inf
dism /unmount-wim /mountdir:mount /commit
del /q mount
echo install.wim的驱动程序已经加载完毕。
set sendcode=加载install.wim的驱动，4
set voice=已经成功加载install.wim的驱动
rd /q/s mount
pause
goto sc


:help
echo ----------------------------------------------------------------
echo                      使用帮助
echo    工作原理：由于键鼠失灵的情况是因为没有驱动程序支持，而键盘鼠
echo 标是通过USB3.0接口与Mac交流，所以只要加载USB3.0的驱动程序即可规避
echo 这一问题。
echo    使用说明：顺序执行1~5项目即可。
echo    版本：1,3,0,0
echo    版权信息：一切版权归第8题选C所有。任何人未经许可不得进行反编译
echo 、修改、违规操作等。
echo ----------------------------------------------------------------
pause
goto input


:exit1
echo 不存在Windows安装镜像，请检查是否运行了复制程序。
echo 即将开始运行复制程序...
pause
goto copy1




:connect
echo 启动QQ后，按任意键继续。
pause
start tencent://Message/?Uin=1784539058
goto input

本文标签： 键鼠 测试 MacBook AIR Pro