DZ FS常用宏命令

DZ宏:

饰品:

#showtooltips 部落勋章

/use 部落勋章

/cast [combat,noexists]消失

/cast [combat,harm]致盲

/cast [nocombat]!潜行

/cleartarget [nocombat]

/targetenemy [nocombat]

/stopmacro [nostealth]

/cast 暗影步

/cast 闷棍

注:徽章使用,战斗无目标消失,战斗有目标致盲,不在战斗潜行,潜行时暗步+闷

凿击闷棍:

#showtooltip [stealth]闷棍;凿击

/cast [stealth]闷棍;凿击

/focus target [harm,nodead,stealth]

注:潜行闷棍,并设目标为焦点,非潜行凿击

肾击钓鱼:

#showtooltip [equipped:鱼竿]钓鱼;肾击

/cast [equipped:鱼竿]钓鱼;肾击

注:装备鱼竿则钓鱼,反之肾击

脚踢投掷:

#showtooltip [stealth]搜索;脚踢

/ins

/stopmacro [help]

/cancelaura 保护之手

/console Sound_EnableSFX 0

/cast [stealth]搜索;脚踢

/cast [equipped:投掷武器]致命投掷

/cast [equipped:投掷武器]!投掷;!射击

/console Sound_EnableSFX 1

/script UIErrorsFrame:Clear()

注:友方观察,取消保护之手,潜行时搜索,非潜脚踢,有星致命投掷,无星投掷,反之射击

缴械闷棍:

#showtooltip 拆卸

/cleartarget [stealth]

/targetenemy [stealth]

/console Sound_EnableSFX 0

/cast [stealth]闷棍;拆卸

/console Sound_EnableSFX 1

/use [equipped:降落伞披风,nostealth]降落伞披风

/script UIErrorsFrame:Clear()

注:潜行时为抓贼宏,非潜行拆卸,非潜行+装备降落伞时则使用降落伞

致盲:

#showtooltips 致盲

/stopattack

/cast [target=mouseover,exists][]致盲

/focus target [nodead,exists]

/script UIErrorsFrame:Clear()

注:停止攻击,鼠标指向致盲,鼠标指向没目标则致盲当前目标,设置当前目标为焦点

选目标:

#showtooltips [equipped:投掷武器]投掷;射击

/clearfocus [target=focus,dead]

/stopattack

/cast 搜索

/console Sound_EnableSFX 0

/cast [stance:3] 闷棍

/console Sound_EnableSFX 1

/script UIErrorsFrame:Clear()

/cleartarget

/targetenemy

注:焦点死亡清除,停止攻击,选择最近敌对目标,影舞时选最近目标闷棍

焦点目标切换暗步:

#showtooltips 暗影步

/target [target=focus,exists]

/targetlasttarget

/focus target

/targetlasttarget

/cast [nodead,harm,exists] 暗影步

注:焦点与当前目标互换,然后暗影步

背刺伏击:

#showtooltip [stance:3][stance:2]伏击;背刺

/duel

/stopmacro [help]

/console Sound_EnableSFX 0

/cast 搜索

/cast 预谋

/cast [stance:3][stance:2]伏击;背刺

/cast [stance:3]奥术洪流

/startattack [nostealth]

/console Sound_EnableSFX 1

/script UIErrorsFrame:Clear()

注:友方目标决斗,影舞潜行时伏击,反之背刺,影舞时洪流伏击

偷袭毒刃:

#showtooltip [stance:3][stance:2]偷袭;毒刃

/f

/stopmacro [help]

/console Sound_EnableSFX 0

/cast 搜索

/cast 预谋

/cast [stance:3][stance:2]偷袭;毒刃

/console Sound_EnableSFX 1

/startattack [nostealth]

/script UIErrorsFrame:Clear()

注:友方目标跟随,影舞潜行时偷袭,反之毒刃

剔骨洪流:

#showtooltip [stealth,spec:2]毁伤;刺骨

/cancelaura 长视术

/cast [nostealth,combat]奥术洪流

/cast [stealth]搜索

/cast [stealth]毁伤;刺骨

/startattack [nostealth]

/use [nocombat,nostealth,nomounted] 1

/script UIErrorsFrame:Clear()

注:副天赋时潜行时毁伤,非潜行时洪流剔骨,不在战斗不在前行不在坐骑时使用工程头(望远镜),再次点击取消

破甲锁喉:

#showtooltip [stance:3][stance:2][stance:1]锁喉;破甲

/stopattack

/cast 预谋

/cast 搜索

/cast [stance:3][stance:2][stance:1]锁喉;破甲

/script UIErrorsFrame:Clear()

/use [nocombat,nostealth]气阀微粒提取器

注:影舞潜行时锁喉,平时破甲并停止攻击,不在战斗不在潜行时使用吸尘器

割裂找贼:

#showtooltips

/cast [nocombat,nostealth]!潜行

/cleartarget [nocombat]

/targetenemy [nocombat]

/console Sound_EnableSFX 0

/cast [stealth]暗影步

/cast [stealth]闷棍;[combat]割裂

/console Sound_EnableSFX 1

/script UIErrorsFrame:Clear()

注:战斗状态下割裂,非战斗状态下潜行,自动选择最近目标暗步闷

要面包:

/script SendChatMessage("大师,能给组面包么,谢谢 :)","whisper",GetDefaultLanguage("target"),UnitName("target"))

注:没有,慎用

随机坐骑斗篷:

/cast [combat][stealth,harm]暗影斗篷

/stopmacro [combat][stealth,harm]

/dismount [mounted]

/userandom [noflyable]黑色作战迅猛龙,紫色骷髅战马

/userandom [flyable]涡轮加速飞行器

注:战斗时或潜行时有敌对目标情况下斗篷,反之随机坐骑,在坐骑上则下坐骑

潜行加强:

#showtooltips [stealth,spec:1]预谋;潜行

/stopattack

/cast [combat][mod:alt]消失

/cast [nocombat,nostealth]!潜行

/cast [stealth]预谋

/targetenemy [noexists][noharm][dead]

/cast [mod:alt]闷棍;偷袭

/script UIErrorsFrame:Clear()

注:潜行时显示预谋CD(主天赋里需要有预谋技能,如果副天赋为敏锐,则把spec:1改为spec:2),停止攻击,不在战斗和潜行的时候潜行,在战斗或alt按下时消失,潜行时偷袭,潜行时按下alt则闷棍

暗步:

#showtooltips 暗影步

/console Sound_EnableSFX 0

/cast [target=mouseover,exists][]暗影步

/cast [stance:3]闷棍

/console Sound_EnableSFX 1

注:鼠标指向暗步,反之暗步当前目标,影舞时暗步+闷

影舞:

#showtooltips 暗影之舞

/cast 偷袭

/cast 暗影之舞

/use 13

/script UIErrorsFrame:Clear()

注:影舞+饰品+偷袭

伺机待发:

#showtooltips 伺机待发

/cast 疾跑

/cast [nostealth]闪避

/cast 伺机待发

注:没有,慎用

扰乱潜行:

#showtooltips 扰乱

/tr

/stopmacro [help]

/cast [nostealth,nocombat]!潜行

/cast [combat]!扰乱;扰乱

注:友方目标交易,扰乱并潜行

起搏器手雷:

#showtooltip [nocombat]地精起搏器XL型;精金手雷

/use [nocombat] 地精起搏器XL型;精金手雷

注:战斗时使用手雷,不在战斗使用起搏器

茶:

#showtooltip 菊花茶

/cancelaura [nocombat]潜行

/use [combat]菊花茶

注:不在战斗时取消潜行,战斗时喝茶

嗑药:

#showtooltips 超级治疗药水

/console Sound_EnableSFX 0

/use [combat]极效治疗石

/use [combat]特效作战治疗药水

/use [combat]超级治疗药水

/console Sound_EnableSFX 1

/script UIErrorsFrame:Clear()

注:没有,决斗时慎用

绷带与急救整合:

#show 厚灵纹布绷带

/cast [button:1] 厚灵纹布绷带;急救(大师级)

注:鼠标左键或快捷键时绷带,右键点击则弹出制作绷带界面

宝石:

/cast [button:1]珠宝加工;[button:2]选矿

/use 铜矿石

/use 锡矿石

/use 铁矿石

/use 秘银矿石

/use 瑟银矿石

/use 魔铁矿石

/use 精金矿石

注:左键珠宝加工界面,右键自动选矿,但需保证背包中的矿为5的倍数

上毒整合:

/use 致伤药膏 V(减速药膏/致命药膏/致命药膏 VII/麻痹药膏/正义武器涂层)

/use [button:1] 16; [button:2] 17

/click StaticPopup1Button1

注:左键点击主武器上毒,右键副武器上毒,自动点击"确定"按钮覆盖原有毒,战场/决斗/JJC/拉人界面弹出时点击则会直接点确定,慎用

双天赋换装:

/equipset [spec:1] Mutilate(此为游戏自带套装名称);Shadowdance(同上)

/usetalents [spec:1] 2; 1

注:切天赋并换上对应天赋的套装

随机宠物带收宠功能:

/run local n,a=GetNumCompanions("CRITTER");if IsAltKeyDown()then for i=1,n do

_,_,_,_,a=GetCompanionInfo("CRITTER", i)if a then

CallCompanion("CRITTER",i)end;end;else CallCompanion("CRITTER", random(n))end

注:随机召唤宠物,按alt点击则收宠

FS宏

按键不够用？技能栏已经满了？你的按键、技能栏位利用率高吗？

你是不是奥术智慧和奥术光辉都在技能栏上？

你是不是技能栏上还有好多坐骑？

你是不是不论什么时候吃喝的图标都占着一个位子？

你有想过这样 "合理" 吗？

比如你的冰箱是G键，放在你的技能栏上以供你察看CD。不错，这个技能固然重要，但是比起冰箭、火球甚至冰环等等，他其实可能是你使用的最少的技能之一，你可能好几分钟或者好几十分钟才用一次。但这样的技能就占了你一个键位一个技能栏……

你有没有想过这些按键有时也可以用来干点儿别的事情？！

——没有做不到，只有想不到！

一、通过手动按键合理压缩冷僻技能。

做为一个PVE玩家，你的增效和抑制是不是几乎从来就没用过?那你怎么办?这两个技能不拖出来吗?格鲁尔的时候又翻翻技能书?拖出来各占一个位置?格子不够用怎么办?

其实对于这类生僻技能，可以通过以下简单宏来将其压缩到一个格子里面：

#showtooltip

/cast [mod:alt] 魔法增效;魔法抑制

平时显示的是抑制，按下alt键时该格子就变成了增效。这样一个格子就很方便的放下了2个技能。相信按个alt比起翻技能书还是方便了不少吧。

注意在使用了#showtooltip语句之后，宏的图标使用?号的话。宏图标和技能说明都会实时自动更新。

同类宏：

#showtooltip

/cast [mod:alt] 奥术光辉;奥术智慧

平时显示的是奥术智慧，按下alt时是奥术光辉。

#showtooltip

/cast [mod:alt] 法力护盾;寒冰护体

平时显示的是寒冰护体，按下alt时是法力护盾。

当然，这种宏其实是通过使用不同激活方式来完成在一个格子里同时放置两个技能。类似还可以通过左右键的不同点击来实现不用的技能调用，比如左键做水右键做面包之类。这在原理上都是相通的。但个人建议使用alt/shift/ctrl。是因为按下这些键的时候你可以清楚的看到技能图标的变化。

二、通过自动的条件判断来合理压缩相关技能。

战斗时你能坐下吃面包吗?非战斗时你会没事喝瓶蓝吗?那对于类似于这种不兼容的技能(物品)你有必要占两个格子吗?

其实对于这类技能，我们也可以通过宏来将其压缩到一个格子里面。与上面不同的是，这类宏是自动判断的。

#showtooltip

/use [combat] 超级法力药水;魔法冰川水

非战斗状态显示的是魔法冰川水，战斗状态显示的是大蓝。当然，你完全可以大蓝换成大红，魔法冰川水也可以换成魔法羊角面包。道理是一样的，我希望让大家明白是这一种思想。做宏很简单的不是吗? 类似的宏还有在A姿态下放技能1，在B姿态下放技能2。如果你是战士或者小德等可能会用到……这里的思想是一样的。

同类宏：

#showtooltip

/use [combat] 超级治疗药水;魔法羊角面包

非战斗状态显示的是魔法羊角面包，战斗状态显示的是大红。

#showtooltip

/use [combat] 法力刚玉;魔法点心

非战斗状态显示的是魔法饼干，战斗状态显示的是法力宝石。

三、目标属性与非技能行为。

你能给你的敌人加buff吗?你能对友好目标施放寒冰箭吗?当然也不行。

那我们为什么不在这个技能对当前目标无法使用时让它有点儿别的用处呢?让我们来看看下面这个宏能干什么。

#showtooltip

/stopcasting

/cancelaura 寒冰屏障

/cast [target=focus,exists,harm,mod:alt]法术反制;[harm]法术反制

/stopmacro [nohelp]

/f

这是一个法术反制宏，目标为敌对时，按下alt键反制焦点，直接按是反制当前目标。当当前目标是友善时，这个宏就变成了跟随宏！

你跟随别人时还是右键跟随目标吗?目标超出距离失败还得重来一次?真是太麻烦了,其实你只需要用这个宏"反制"他就行了……

这里的/f还可以换成

/ins(观察)

/tr(交易)

这意味着你可以把上面宏小小的修改一下，你就可以对着一个目标点一下"冰箭"就可以观察他，或者是想"交易"一个目标的时候给他一个"冰枪"！由于这些常用的技能往往都放在比较舒服的键位，所以你现在完全可以更方便更快速的跟随、观察和交易了。

同类宏:

#showtooltip 火焰冲击

/cast [harm] 火焰冲击

/stopmacro [nohelp]

/ins

对敌对目标就是普通的火冲，对于友善目标就是观察。

四、宠物技能、宠物状态、焦点与其它技能整合

你还在用手点宠物技能条?手用右键设焦点?还是专门写了一个焦点宏?其实这些通通很浪费。

对于某些需要指定范围、需要读条的技能，我们可以通过宏来让他们绑定更多立即实现的功能，例如：设置焦点，宠物攻击等。

我们来看看以前某些牛人留下的两个现成的宏：

#showtooltip [target=pet,nodead,exists] 冰冻术;召唤水元素

/cast 冰冻术

/petpassive

/petattack [harm]

/petfollow [noharm]

/stopmacro [target=pet,nodead,exists,nomod]

/run if(GetSpellCooldown('急速冷却')==0) then PetDismiss() end

/cast [mod:alt] 急速冷却

/cast 召唤水元素

以上宏的作用是，没有水元素的时候，召唤水元素。有水元素的时候，施放冰冻术。

但并未非完全如此。由于冰冻术是非立即施放法术(要先确定施法范围)所以这个宏里还额外带了很多立即施放的功能。

当前目标可攻击时为宝宝攻击，当前目标不可攻击时为宝宝跟随。当急速冷却没有在CD中的话，按alt点这个宏是解散当前宝宝，并重新召唤一个！

刚召出来的宝宝是被动而且不攻击的，希望让他攻击当前目标只需要再点一下该宏即可实现。

#showtooltip

/castrandom [mod:alt,target=focus,exists] 变形术(等级 4),变形术(猪),变形术(龟)

/stopmacro [mod:alt]

/clearfocus [noexists]

/stopmacro [noexists]

/focus [exists]

/petfollow [target=pettarget, exists]

/castrandom 变形术(等级 4),变形术(猪),变形术(龟)

以上宏将羊、焦点、宝宝跟随绑定在一个键位上。你羊目标的同时会设当前目标为焦点(即设你的羊为焦点)，当前目标为空时又会清除焦点，宝宝跟随是为了防止宝宝攻击你正在羊的目标。这个宏其实是为了变形术写的，但我们同样可以用这个宏来设置焦点、清除焦点。对于某些不能羊的对象，设置焦点、清除焦点功能同样有效。比如对于双子，需要将火女设焦点，你可以先“羊”一下她，这样就设好焦点了。

五、解放你的TAB键、目标切换与技能绑定

做为一个治疗者，你可能绝大多数时候都没有办法为一个怪物加血。而做为一个伤害输出者，你可能永远都没有办法给你的队友来一个冰箭。那我们有没有办法让你的寒冰箭在对准盟友时让它干点别的事情呢？答案是肯定的！

#showtooltip

/assist [help]

/cast [harm] 寒冰箭

对敌对目标施放寒冰箭，对友善目标，这个宏就变成了协助攻击宏——切换你的目标为你队友的目标。当然，你可以把这个宏改成不丢失当前目标只是对你队友的当前目标施放一个寒冰箭或者其它怎么样，这并不是重点。我所希望传达的思想其实是，在你的技能某些时刻无法使用或无需使用的时候，让你的技能栏不那么的没用——他们可都占着好地方和好键位呢！

同类宏：

#showtooltip

/target [harm] targettarget

/cast 治疗链

这是一个萨满的治疗链宏。你可以选中Boss然后为Boss的当前目标刷治疗链，如果你不想这个宏丢失你的当前目标，你可以再加一句：

/targetlasttarget

#showtooltip

/targetfriend [help]

/cast [harm] 火球术

这是一个简单的火球术宏，但当你的目标是队友的时候，这个宏就变成了在队友之间切换目标的宏。相当于ctrl+TAB。类似的，我们也可以把一些无法对敌对目标使用的技能与TAB绑定，例如下面这个宏。

#showtooltip

/targetenemy [harm]

/cast [help] 魔法专注

这样你的魔法专注就同时有了TAB的功能。当然，这只是一个例子，你完全可以把这个功能绑定到缓落术或者其它任何你觉得合适的技能上面！

六、技能冷却时你能做什么与castsequence。

有没有想过你的龙息、冲击波这些技能占着你的快捷键和技能栏。但是这些技能较长的冷却时间决定了你这些按键与技能栏的利用率相当低下。在这些技能CD的时候你有没有想过让这些按键干点别的事情呢?让我们来看看下面这些宏。

#showtooltip

/castsequence reset=20 龙息术,火球术,火焰冲击

这是一个很古老的龙息三连击的宏，这里使用了castsequence命令来序列执行技能。你只需要一直按这个宏就可以完成龙息三连击了。但castsequence有一个致命的缺点就是不支持急速冷却，所以一般不建议冰法用来做盾或冰环的宏。但这只是攻击性的宏有这样的不便，技能冷却的时候，我们除了使用其它技能，当然也可以干点别的不是么。看看下面这个宏。

#showtooltip

/run if(GetSpellCooldown('急速冷却')<>0) then print("靠,老子CD还没好,你按什么按!") end

/cast 急速冷却

这个宏在你的急冷没有冷却的时候会在聊天窗里打出一行白字提示。当然，你可以换成其它任何语句。或者提示你的队友你的技能还有多久CD。例如下面这个宏。

#showtooltip

/run local s,c=0,0;s,c=GetSpellCooldown('寒冰护体'); if(s>0) then

SendChatMessage("我的寒冰护体还有

"..("%4.1f",c+s-GetTime()).." 秒冷却！","SAY") end;

/cast 寒冰护体

这个宏平时就是一个寒冰护体的宏，但当你的寒冰护体在冷却中的时候，这个宏就变成了提示你的队友或身边人你的技能还有多久冷却的宏。当然你也可以对这个宏进行修改，要换成你需要的技能。

目前先想到这些，希望能对大家有所启发，以上这些就权当抛砖引玉，同时召唤没有头的牛头人们来补充。当然，大家在整合技能的同时，一定要注意这个东西的合理性，有些看似很好很强大的宏，其实并不是实用。由于各人的按键习惯，技能使用频率差异比较大，不可能写一个宏就满足所有人的要求，所以我这篇帖子主要是给大家提供一种想法或一种思路，而这里面的提到的宏主要也是做为一些例子供大家参考。希望能对大家有所帮助吧！